*كود* تغيير خيارات بدء التشغيل برمجيا

بارك الله فيك

لقد سألت عن هذا الموضوع كثيراً ولم اجد الحل وهاهو يأتي بدون سؤال

الله لا يحرمنا منك يا ابو حمود

بس لو يكون فيه مثال يخدمنا كثير ومسكور في كل الحالات

مثال عنها كلها كثير ويأخذ وقت .

إذا فيه شيء ما فهمته منها اكتب وأنا أوضح لك إن شاء الله .

ولك تحياتي

مشكور ياابوحمود بس فكرت عندك واحد جاهز

هل ترغب في أن أعيد شرحها بحيث يكون الشرح بعد كل سطر .

إن كنت ترغب في هذا فآمر .

ولك تحياتي

الله يعطيك العافيه على هالموضوع الممتاز

مشكوووور يابوحمود لاتسلم ماقسرت

بسم الله الرحمن الرحيم

الأخ الفاضل / ابو حمود .. كيف حالك

ياريت لو تتكرم كما قلت بشرح لكل امر حتى تكمل الفائدة ويعد بمثابة درس ... هذا إذا لم يكن الأمر فيه تحميل عليك .. الله يعينك علينا :) :)

شكرا لك

فى انتظارك

تقبل تحيات

أخـــــBengaـــوك

اليكم إعادة للشرح :

لتغيير الإعدادات في مربع حوار بدء التشغيل StartUp

مربع حوار بدء التشغيل يتحكم في الكثير من الخصائص الخاصة بقاعدة البيانات وقد وضعت هذه الخيارات منفصلة عن خيارات قاعدة البيانات لأنها تختص بقاعدة البيانات المفتوحة ، يبدأ عمل مربع حوار بدء التشغيل قبل بدء ماكرو Autoexec فور تشغيل القاعدة .

للوصول إلى مربع حوار بدء التشغيل انقر على قائمة أدوات ثم بدء التشغيل .

بعض الخيارات الموجودة في مربع حوار بدء التشغيل تعمل مباشرة عند تغييرها والبعض الآخر تعمل عند فتح قاعدة البيانات مرة أخرى وبإمكانك تجاوز خيارات بدء التشغيل بالضغط على Shift مالم يعطل هذا الخيار .

==================================

أولا : عنوان وأيقونة التطبيق

(ملاحظة 1و2 يستدعيان نفس الدالة)

1- عنوان التطبيق Application Title

يظهر هذا العنوان في شريط الأكسس وفي إطار قاعدة البيانات إذا لم تكن مبكرة بالحد الأقصى يزيل هذا العنوان العنوان الافتراضي لأكسس ، لتغيير العنوان برمجيا ضع في حدث عند النقر على زر الأمر مثلا الكود التالي :

Dim intX As Integer 
Const DB_Text As Long = 10 
intX = AddAppProperty("AppTitle", DB_Text, "عنوان جديد") 
intX = AddAppProperty("AppIcon", DB_Text, "C:WindowsCars.bmp") 
Application.RefreshTitleBar

السطر الثاني في الكود السابق : إعلان عن ثابت من النوع Long ويمكنك حذف العبارة السابقة واستبدالها في السطر الثالث بـ dbtext أو db_text أو كتابة رقم 10 في نفس الموضع .

السطر الثالث : تم وضع المتغير intX لتخزين القيمة العائدة من الدالة المعرفة من قبل المستخدم AddAppProperty تعيد الدالة إذا تم تغيير العنوان بنجاح قيمة -1 وإذا لم يتم تغيير العنوان 0 .

ثم الوسيطة الأولى اسم الخاصية في الأكسس والثانية نوعها والثالثة العنوان الجديد .

إذا لم ترغب في حفظ القيمه العائدة من الدالة فاحذف المتغير ويساوي والأقواس لتكون العبارة كالتالي :

AddAppProperty "AppTitle", DB_Text, "عنوان جديد"

السطر Application.RefreshTitleBar ليظهر العنوان الجديد مباشرة وإذا لم تضعها يتم حفظ العنوان الجديد في مربع الحوار بدء التشغيل دون ظهوره في الشريط العلوي لأكسس حتى تقوم بتشغيل قاعدة البيانات مرة أخرى .

إذا كنت تريد تمكين المستخدم من تغيير العنوان بدون اللجوء إلى مربع حوار بدء التشغيل فاستخدم دالة InputBox كالتالي :

intX = AddAppProperty("AppTitle", DB_Text, InputBox("اكتب العنوان الجديد:"))

ملاحظة هامة : إذا كان عنوان القاعدة فارغ واستخدمت السطر السابق لمطالبة المستخدم بالعنوان الجديد ولكن المستخدم نقر زر Cancel ولم يضع عنوان فستظهر رسالة الخطأ التالية (الخصائص المعرفة من قبل المستخدم لاتدعم القيم الخالية) ولتصحيح الخطأ اكتب عبارة من عبارات معالجة الخطأ أو أعد مطالبة المستخدم أو أنظر ما يأتي .

وبإمكانك اسناد قيم موجودة في جدول أو استعلام أو وضع حدث Timer لتغيير العنوان بشكل متتابع وغير ذلك .

لمسح العنوان الذي كتبته اكتب :

intX = AddAppProperty("AppTitle", DB_Text, " ")

انتبه ضع مسافة بين الفاصلتين المزدوجتين .

2- السطر الرابع في الكود السابق :

intX = AddAppProperty("AppIcon", DB_Text, "المسار واسم الأيقونة أو ملف الصورة")

هذا السطر خاص بوضع أيقونة للبرنامج أو تغييرها أو حذفها .

ملاحظة : لحذف الأيقونة :

intX = AddAppProperty("AppIcon", DB_Text, "")

تظهر الأيقونة في الجزء العلوي الأيسر من الشاشة .

أما إذا أردت تغيير الأيقونة الخاصة بالقاعدة التي تظهر على ملفات الأكسس (المفتاح) فاجعل للقاعدة إختصار مثلاً على سطع المكتب ثم انقر عليه بزر الفأرة الأيمن واختر خصائص ثم تغيير الرمز ثم اختر الأيقونة المناسبة وإذا كانت الأيقونة موجودة في ملف آخر فاختر ملف الأيقونة من نوع ICO أو Exe أو dll أو غيرها من الملفات حسب نوع الملف الموجودة فيه ، ولتغير الأيقونة في قائمة أبدأ اعمل نفس الطريقة السابقة وأما تغيير أيقونة الملف نفسه فلا أعرف طريقتها وهناك برامج لتغيير الأيقونات .

طبعاً يمكنك تغير العنوان فقط أو تغيير الأيقونة فقط أو كلاهما .

--------------------------------------------

الحدث السابق يستدعي الدالة التالية :

--------------------------------------------

Function AddAppProperty(strName As String, varType As Variant, varValue As Variant) As Integer 
On Error GoTo AddProp_Err 
Dim dbs As Object, prp As Variant 

Const conPropNotFoundError = 3270 
Set dbs = CurrentDb 
dbs.Properties(strName) = varValue 
AddAppProperty = True 

AddProp_Bye: 
Exit Function 
AddProp_Err: 
If err = conPropNotFoundError Then 
Set prp = dbs.CreateProperty(strName, varType, varValue) 
dbs.Properties.Append prp 
Resume 
Else 
AddAppProperty = False 
Resume AddProp_Bye 
End If 
End Function

وعملها يتلخص في البحث عن العنوان أو الإيقونة السابقة في مربع حوار بدء التشغيل ، فإذا لم يجدهما (أي قيمهما في مربعي النص الخاص بكل منهما) أو أحدهما يعطي خطأ فيبدأ تنفيذ الأسطر بعد الخطأ .

ولقراءة خاصية العنوان :

Dim dbs As Database 
Set dbs = CurrentDb 
MsgBox dbs.Properties![AppTitle] 
dbs.Close

لكن لاحظ أن الطريقة السابقة تكون بعد إنشاء العنوان أو الأيقونة أو كتابتهما من قبل المستخدم وإلا ستظهر رسالة الخاصية غير موجودة .

ولقراءة خاصية الأيقونة :

Dim dbs As Database
Set dbs = CurrentDb
MsgBox dbs.Properties![AppIcon]
dbs.Close

======================================

(ثانياً) لتغيير بقية خيارات مربع حوار بدء التشغيل :

أعلن عن الثابتين التاليين :

 Const DB_Text As Long = 10 
 Const DB_Boolean As Long = 1

1- تشغيل نموذج عند بدء تشغيل القاعدة :

ChangeProperty "StartupForm", db_Text, "اسم نموذج”

لاختيار النموذج الذي يفتح عند بدء تشغيل البرنامج واسمه في مربع حوار بدء التشغيل (عرض النموذج/الصفحة).

لعدم عرض نموذج عند بدء التشغيل استبدل اسم النموذج بالعبارة التالية "(None)" .

غالباً ما يستخدم لتشغيل لوحة التبديل Switchboard أو وضع صورة على نموذج وجعلها مثل النوافذ التي تظهر عند بدء تشغيل الأكسس أو الوورد أو غيرهما من البرامج وتكون ذات تنسيق جيد وباسم البرنامج وبدون حدود للنموذج ، مع تشغيل حدث المؤقت لإغلاقها بعد مرور ثلاث ثواني مثلا .

فائدة : بإمكانك إظهار صورة عند بدء تشغيل قاعدة بوضع الصورة في نفس مجلد القاعدة وتغيير اسمها إلى نفس اسم القاعدة ولكن يعيب هذه الطريقة سرعة ظهور وإختفاء الصورة ولو أمكن التحكم بسرعة ظهورها لكانت أفضل من طريقة وضع صورة على نموذج .

2- إظهار أو إخفاء إطار قاعدة البيانات :

ChangeProperty "StartupShowDBWindow", DB_Boolean, قيمة

إطار قاعدة البيانات هو الإطار الذي يحوي كائنات التطبيق من الجداول والاستعلامات والنماذج والتقارير وصفحات البيانات والماكروات والوحدات النمطية .

لعرض إطار قاعدة البيانات اجعل مكان قيمه True ولعدم ظهوره اجعل False .

قد تحتاج إلى إخفاء الإطار لغرض عدم تمكين المستخدم من الاطلاع على كائنات القاعدة أو التعديل فيها وهو خيار أفضل لكن مع مراعاة تمكين المستخدم من وظائف القاعدة لا أن تدعه أمام إطار فارغ .

لإظهار الإطار انقر F11 ، يبدأ التطبيق بعد التشغيل التالي لقاعدة .

3- عرض أو إخفاء شريط المعلومات

ChangeProperty "StartupShowStatusBar", DB_Boolean, قيمة

لإظهار أو إخفاء شريط المعلومات وهو الشريط الذي يظهر في أسفل الأكسس ضع بدلا من القيمة True لعرض الشريط و False لإخفاءه .

4- منع أو السماح بأشرطة الأكسس الافتراضية في مربع حوار بدء التشغيل اسمها السماح بأشرطة الأدوات المضمنة

 ChangeProperty "AllowBuiltinToolbars", DB_Boolean, قيمة

إظهار أشرطة الأدوات الافتراضية لأكسس ضع بدلاً من القيمة True ولإخفائها False .

عند منع أشرطة الأدوات المضمنة تختفي كل الأشرطة الخاصة بالأكسس وتبقى الأشرطة الخاصة بالتطبيق (التي من إعداد المبرمج) .

5- السماح بالقوائم الكاملة

 ChangeProperty "AllowFullMenus", DB_Boolean, قيمة

تختفي القوائم الافتراضية الخاصة بالأكسس وتظهر قوائم محدودة تختص بالتحرير والطباعة والتعامل مع السجلات والإطارات والتعليمات وهي تفي بحاجة المستخدم من حيث إدخال وعرض البيانات خاصة إذا لم ترغب في إنشاء قوائم خاصة بالتطبيق .

لإظهار القوائم الكاملة ضع بدلاً من قيمة True ولإخفائها False .

وإخفاء القوائم الكاملة مع إخفاء الأشرطة الإفتراضية لأكسس مفضل جداً حتى لايستطيع المستخدم تغييير تصميم قاعدة البيانات .

6- منع المستخدم من مقاطعة الإجراءات بضغط Ctrl+Braek

ChangeProperty "AllowBreakIntoCode", DB_Boolean, قيمة

تمنع المستخدم من إيقاف الإجراء الطويل بالنقر على زري Ctrl+Break .

ضع بدلاً من قيمة True لمنع مقاطعة الإجراءات وFalse للسماح له بذلك ، وفي التعليمات الخاصة بالأكسس هذه العبارة :

You can use the AllowBreakIntoCode property to specify whether or not the user can view Visual Basic code after a run-time error occurs in a module.

ولكن بعد التجربة لم ألحظ أنها تمنع المستخدم من الاطلاع على الوحدة النمطية في حالة حدوث الخطأ فما أدري أين الخطأ ؟ .

7- استخدام مفاتيح وصول خاصة

ChangeProperty "AllowSpecialKeys", DB_Boolean, قيمة

لمنع أو السماح للمستخدم من استخدام للمفاتيح التالية :

(ALT+F1 (F11), CTRL+F11, CTRL+BREAK, and CTRL+G)

فالأولى للوصول إلى إطار قاعدة البيانات وجلبه إلى الأمام والثاني للتبديل بين شريط القائمة المخصص وشريط القائمة المضمن والثالث لإيقاف التعليمات البرمجية والرابع لإظهار إطار التصحيح Dubeg .

Ctrl+F11 : إذا تم اختيار شريط قوائم مخصص في مربع حوار بدء التشغيل يظهر مباشرة عند فتح القاعدة ويخفي قوائم الأكسس الافتراضية وعند النقر على مفتاح Ctrl+F11 يختفي شريط القوائم المخصص ويظهر شريط القوائم الخاص بالأكسس ، قد يكون هنام صعوبة في فهمها ولكن انقر على أدوات ثم تخصيص ثم جديد ثم اكتب اسم لشريط الأدوات الجديد ثم سيظهر في قائمة أشرطة الأدوات اختاره ثم انقر على زر خصائص ثم حوله الى شريط قوائم ثم إغلاق ثم ضع فيه القوائم التي ترغب في ظهور وسواء تختار من القوائم المضمنه أو القوائم الجديدة ثم إغلاق ثم افتح مربع حوار بدء التشغيل وانتقل الى شريط القوائم تجد اسم القائمة التي أنشأتها اخترها ثم موافق ثم أغلق القاعدة وأعد تشغيلها ستجد شريط القوائم قد ظهر واختفى شريط القوائم الخاص بالأكسس اضغط Ctrl+F11 سيختفي الشريط ويظهر شريط القوائم الافتراضي الخاص بأكسس .

إذا لم ترغب في ظهور شريط القوائم المخصص فاضغط Shift باستمرار أثناء فتحه القاعدة لتعطيل خيارات مربع حوار بدء التشغيل على أنه بإمكانك إظهار شريط القوائم بالنقر بزر الفأرة الأيمن على شريط الأدوات واختيار تخصيص ثم اختيار شريط القوائم ثم إغلاق إذا لم يعطل كما سيأتي .

8- منع أو السماح بتأثير Shift عند بدء تشغيل القاعدة

هذا الخيار غير ظاهر في مربع حوار بدء التشغيل وطريقته :

ChangeProperty "AllowBypassKey", DB_Boolean, قيمة

منع المستخدم من إيقاف الماكرو AutoExec أو الخيارات المحددة في بدء التشغيل عن طريق ضغطه لـ Shift عند بدء فتح قاعدة البيانات . استبدل قيمه بـ True لتمكين تأثير Shift وFalse لإيقاف تأثيرها .

9- السماح بتغييرات أشرطة الأدوات القوائم

ChangeProperty "AllowToolbarChanges", DB_Boolean, قيمة

يعطل أمر تخصيص في قائمة أدوات وكذلك لاتظهر القائمة اليمنى عند النقر بزر الفأرة الأيمن على قائمة أو شريط أدوات .استبدل قيمه بـ True للسماح بالتغيير وFalse للمنع من التغيير .

10- السماح بالقوائم المختصرة الافتراضية

ChangeProperty "AllowShortcutMenus", DB_Boolean, قيمة

وهي القوائم التي تظهر عند النقر على أحد كائنات القاعدة بزر الفأرة الأيسر لتنفيذ أوامر على هذا الكائن فمثلا النقر بزر الفأرة الأيمن على النموذج تظهر قائمة تحوي تصميم النموذج – طريقة عرض صفحة البيانات – خصائص وقد تتغير هذه بنود القوائم حسب خيارات أخرى . استبدل قيمه بـ True للسماح بظهور القوائم المختصرة الافتراضية وFalse للمنع .

11- شريط القوائم المختصرة

ChangeProperty "StartupShortcutMenuBar", db_Text, "اسم شريط منبثق”

لإظهار شريط قوائم مختصر للتطبيق ككل (ويسمى في مربع حوار تخصيص منبثق) ، تظهر هذه القائمة عند النقر بزر الفأرة الأيسر على الجداول أو الاستعلامات أو النماذج أو التقارير مالم تخصص شريط قوائم منبثق لأحدها ، وإذا رغب أحد في تعلم كيفية إنشاء قائمة منبثقة كتبتها له .

ولإزالة الشريط المختصر :

ChangeProperty "StartupShortcutMenuBar", DB_Text, "(default)"

12- شريط القوائم

ChangeProperty "StartupMenuBar", db_Text, "اسم شريط قوائم”

تخصيص شريط قوائم للقاعدة ككل يظهر عند بدء تشغيل القاعدة ، ولإزالته :

ChangeProperty "StartupMenuBar", db_Text, "(default)"

13- استخدام التقويم الهجري

ChangeProperty "HijriCalendar", DB_Boolean, قيمة

لاستخدام التقويم الهجري أو غيره ، غير قيمه إلى True لاستخدام التقويم الهجري وإلى False لجعل التقويم ميلادي .

----------------------------------------------------------

جميع أسطر الكود السابقة تستدعي الدالة التالية :

---------------------------------------------------------

Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer 
On Error GoTo Change_Err 
Dim dbs As Object, prp As Variant 
Const conPropNotFoundError = 3270 

Set dbs = CurrentDb 

dbs.Properties(strPropName) = varPropValue 
ChangeProperty = True 

Change_Bye: 
Exit Function 

Change_Err: 
If err = conPropNotFoundError Then 
Set prp = dbs.CreateProperty(strPropName, varPropType, varPropValue) 
dbs.Properties.Append prp 
Resume Next 
Else 
ChangeProperty = False 
Resume Change_Bye 
End If 
End Function

طريقة مختصرة لتغيير أحد القيم السابقة بعد إنشائها بالدالة السابقة :

Dim dbs As Database 
Set dbs = CurrentDb 
dbs.Properties![اسم الخاصية] = False 
dbs.Close 
وللقراءة أسند القيمة العائدة إلى متغير :
Dim dbs As Database 
Dim Rr
Set dbs = CurrentDb 
Rr= dbs.Properties![اسم الخاصية] 
dbs.Close

أرجو أن يكون واضحاً ولا يقول لي أحد أعده مره أخرى .

إذا فيه شيء غير مفهوم أنا مستعد بالإجابة حسب استطاعتي .

ولكم تحياتي

للرفع

الأخوة الأعضاء

ترى الموضوع نافع جدا ولا بد المبرمج في يوم يحتاجه .

انسخ الكود عندك أو احفظ الصفحة .

وللجميع تحياتي